Линейка управляемых коммутаторов Cloud Switch series от Mikrotik постоянно пополняется новыми моделями. Сегодня речь пойдёт о Сloud router switch – CRS326-25G-2S+ RM. Распаковку коммутатора можно посмотреть на YouTube канале asp24.com.ua .
Фанаты Mikrotik отлично знают расшифровку названия модели, а для тех, кто не в курсе – это сделаю я. Буквы CRS определяют принадлежность к линейке, первая цифра 3 обозначает серию, вторая и третья обозначают суммарное колличество портов – 26. Далее идёт 24G – обозначает наличие двадцати четырёх гигабитных езернет портов, 2S+ указывает на наличие двух SFP+ портов. RM обозначает rack-mount, а это значит – возможность установки в девятнадцати дюймовую стандартную стойку. Кстати, в портфолио Mikrotik есть модель, которую можно спутать с нашим сегодняшним коммутатором. Эта модель принадлежит к линейке Cloud smart switch, наименование всё то же 326-25G-2S+ RM, и если название у них практически одинаковое, то внешне различия есть. Хардварно коммутатор из линейки CRS значительно превосходит CSS и имеет самое важное отличие – возможность работать с двумя ОС. В данный момент портфолио коммутаторов Mikrotik насчитывает 2 линейки CSS, CRS и 5 серий: CSS1xx(RB260), CSS3xx, CRS1xx, CRS2xx, CRS3xx.
Теперь вернёмся непосредственно к CRS326-25G-2S+ RM. В текущий момент коммутаторы от Mikrotik не очень жалуют, в связи с тем, что настройка и проброс vlan-ов устроен крайне неудобно, а SwOs вообще придумали, дабы сломать мозг сетевым администраторам. Давайте я попытаюсь развеять этот миф, и мы вместе поймём, как это делается.
Все коммутаторы линейки CRS, CSS оснащены так званным Switch Chip, который позволяет обрабатывать vlan-ы на хардварном уровне, что даёт существенный прирост производительности. Сами характеристики CRS минимальны: CPU мощностью 800 МГц, 512 МБ ОЗУ и 16 постоянной, поэтому здесь рулит Switch Chip Marvell-98DX3236 (он же в роли CPU). Подробнее о коммутации линейки CRS3xx можно узнать в официальном wiki Mikrotik.
Первым делом естественно обновляем ROS, затем обновляем загрузчик:
/system routerboard print
Сравниваем версии, если “upgrade” новее “current”, то необходимо обновить загрузчик. (В случае некорректного обновления, всегда можно воспользоваться резервным загрузчиком, чтобы воспользоваться им, нужно удерживать кнопку сброса до подключения питания!)
/system routerboard upgrade
/yes
У меня собран тестовый стенд из оборудования Mikrotik, где RB3011 – маршрутизатор, CRS326-25G-2S+ RM – коммутатор №1, hex (RB750gr3) – коммутатор №2. Везде установлена ROS 6.46.5, все настройки осуществляем через Terminal.
Начиная с RouterOS 6.41, программисты Mikrotik в корне переписали настройку vlan-ов. Наверное все помнят тот момент, когда после обновления исчезло понятие master-port, и у многих посыпались конфиги. В 6.41 работа с Switch chip стала намного удобнее, vlan-ы теперь настраиваются во вкладке bridge. Информации о таковых схемах настройки очень мало, помимо официального wiki Mikrotik в интернете крайне мало мануалов на данную тему. Всё то, что вам предлагает поисковик – давно устарело, поэтому сегодня эта статья для всех – кто хочет познать новое.
Внимание! Конфигурация с использованием Switch chip задействована только на CRS!
Access and trunk Router OS
Рис.1. Тестовый стенд Access and trunk
Первым делом сконфигурирую наиболее распространённую схему настройки коммутаторов, применяемую в любой жилой многоэтажке, где есть trunk и access порты, то бишь мы прогоняем магистральные vlan-ы (tagget) дальше, абонентский выдаем на порты (untagged). Не буду зацикливаться на настройке шейпера и файервола, сегодня только vlan-ы в разных конфигурациях.
Рис.2. Схема vlan-ов (Access and trunk)
Интернет приходит на RB3011 – 1005 vlan tagged, принимаем его и настраиваем, тип подключения DHCP, также подымаем NAT.
/interface ethernet
set 0 name=eth1_uplink
/interface vlan
add name=vl_1005_uplink interface=eth1_uplink vlan-id=1005
/ip dhcp-client
add interface=vl_1005_uplink disabled=no
pr
Flags: X – disabled, I – invalid, D – dynamic
# INTERFACE USE-PEER-DNS ADD-DEFAULT-ROUTE STATUS ADDRESS
0 vl_1005_uplink yes yes bound 192.168.30.10/24
/ip firewall nat add chain=srcnat action=masquerade out-interface=vl_1005_uplink
Интернет настроен, приступаем к конфигурации vlan-ов на RB3011.
/interface bridge add name=bridge vlan-filtering=no
/interface bridge port add bridge=bridge interface=sfp1
/interface bridge vlan
add bridge=bridge tagged=bridge,sfp1 vlan-ids=21
add bridge=bridge tagged=bridge,sfp1 vlan-ids=22
/interface vlan
add interface=bridge name=vl_21_mngmt vlan-id=21
add interface=bridge name=vl_22_dhcp vlan-id=22
/ip address
add address=172.14.15.1/24 interface=vl_21_mngmt
add address=192.168.0.1/24 interface=vl_22_dhcp
/interface bridge set bridge vlan-filtering=yes
Vlan-ы подготовлены, теперь подымаем dhcp-server, создаём пул адресов.
/ip pool
add name=dhcp ranges=192.168.0.10-192.168.0.250
/ip dhcp-server
add address-pool=dhcp authoritative=after-2sec-delay disabled=no interface=vl_22_dhcp name=vl_22_dhcp
/ip dhcp-server network
add address=192.168.0.0/24 dns-server=8.8.8.8 gateway=192.168.0.1 netmask=24
На этом настройка RB3011 закончена.
Лайфхак! Если вы наблюдаете нагрузку CPU 15-20% в режиме простоя на устройствах Mikrotik с LCD дисплеем , можете просто выключить его.
/tool profile cpu=total
NAME CPU USAGE
spi 15.7%
console 0%
winbox 0%
management 0%
unclassified 0.5%
total 16.2%
/lcd set enabled=no
/tool profile cpu=total
NAME CPU USAGE
spi 0%
console 0%
winbox 0%
management 0%
profiling 0%
unclassified 0%
total 0%
Теперь на CRS наруливаем vlan-ы. В SFP1 порт пришли 21, 22 vlan-ы tagged, с 9 по 16 порт отдаём 22 vlan untagged на абонентов, и далее с eth1 уходят 21, 22 vlan-ы tagged.
/interface bridge add name=bridge vlan-filtering=no
/interface ethernet set 24 name=sfpplus1_uplink
/interface bridge port
add bridge=bridge interface= sfpplus1_uplink
add bridge=bridge interface=ether1
add bridge=bridge interface=ether9 pvid=22
add bridge=bridge interface=ether10 pvid=22
add bridge=bridge interface=ether11 pvid=22
add bridge=bridge interface=ether12 pvid=22
add bridge=bridge interface=ether13 pvid=22
add bridge=bridge interface=ether14 pvid=22
add bridge=bridge interface=ether15 pvid=22
add bridge=bridge interface=ether16 pvid=22
/interface bridge vlan
add bridge=bridge tagged=bridge,sfpplus1_uplink,ether1 vlan-ids=21
add bridge=bridge tagged= sfpplus1_uplink,ether1 vlan-ids=22 untagged=ether9,ether10,ether11,ether12,ether13,ether14,ether15,ether16
Vlan-ы настроены, теперь подымаем управление, применяемая конфигурация подходит – если коммутатор будет управляться исключительно через vlan-ы поданные tagged.
/interface vlan add interface=bridge name=vl_21_mngmt vlan-id=21
/ip address add address=172.14.15.2/24 interface=vl_21_mngmt
/ip route add gateway=172.14.15.1
/interface bridge set bridge vlan-filtering=yes
Коммутатор настроен и для проверки, будучи подключённым к абонентскому порту CRS, я решил погонять скорость, и посмотреть на нагрузку CPU коммутатора. Основную часть трафика, около 450 Мбит, я сгенерировал старым добрым приложением от Mikrotik – Btest для ОС Windows. Результаты меня порадовали, нагрузка CPU CRS326-25G-2S+ RM не превысила 1%, а вот CPU RB3011 показал 45% загрузку в среднем при нагрузке Btest+speedtest.net.
Рис.3. Нагрузка с помощью Btest
Лайфхак! Пока я писал эту статью, Mikrotik обновили дизайн своего фирменного приложения Bandwidth test и выкатили на него ссылку на оф сайте.
Рис.4. Старый и новый дизайн приложения Bandwidth test
Теперь настройка коммутатора №2 hEX (750Gr3). В eth1 принимаем tagged 21, 22 vlan-ы, 22 untagged на eth2-4. На eth5 для управления наруливаю 21 vlan tagged.
/interface bridge add name=bridge vlan-filtering=no
/interface vlan add name=vl_21_mngmt interface=bridge vlan-id=21
/interface bridge port
add bridge=bridge interface=ether1
add bridge=bridge interface=ether2 pvid=22
add bridge=bridge interface=ether3 pvid=22
add bridge=bridge interface=ether4 pvid=22
add bridge=bridge interface=ether5 pvid=21
/interface bridge vlan
add bridge=bridge tagged=bridge,ether1 untagged=ether5 vlan-ids=21
add bridge=bridge tagged=ether1 untagged=ether2,ether3,ether4 vlan-ids=22
/ip address
add address=172.14.15.3/24 interface=vl_21_mngmt
/ip route add gateway=172.14.15.1
/interface bridge set bridge vlan-filtering=yes
Итак, между тремя устройствами соединение 1 Гбит, и с помощью Bandwidth test, я прогнал тест с hEX на RB3011 через CRS. В результате нагрузка на CPU CRS326-25G-2S+ RM не превысила 5%.
Рис.5. Bandwidth test
CPU hEX и RB3011 в результате генерирования трафика оказались загружены на 60%.
Trunk and hybrid ports Router OS
При данной схеме на порт отдаются vlan-ы как tagged, так и untagged одновременно, всё это крайне любопытно, так как практического применения я не встречал, но почему бы не реализовать. На RB2011UAS-2HnD-IN – настройки те же что и в схеме Access and trunk. CRS326-25G-2S+RM обнуляем настройки:
/interface bridge и все подпункты этого меню, vlan-mngmt и адресацию.
Рис.6. Схема vlan-ов (Trunk and hybrid)
Итак, следующие манипуляции: на sfpplus1 принимаем 21, 22 vlan-ы tagged, с eth1 на hEX (750Gr3) отправляем 21 vlan tagged, 22 vlan untagged.
/interface bridge add name=bridge vlan-filtering=no
/interface bridge port
add bridge=bridge interface=sfpplus1
add bridge=bridge interface=ether1 pvid=22
/interface bridge vlan
add bridge=bridge tagged=bridge,sfpplus1,ether1 vlan-ids=21
add bridge=bridge tagged=sfpplus1 untagged=ether1 vlan-ids=22
/interface vlan add name=vl_21_mngmt interface=bridge vlan-id=21
/ip address
add address=172.14.15.2/24 interface=vl_21_mngmt network=172.14.15.0
/ip route
add distance=1 gateway=172.14.15.1
/interface bridge set bridge vlan-filtering=yes
Дошла очередь настройки hEX (750Gr3), точнее проверка нашей схемы. Конфиг таков:
/interface vlan
add interface=ether1 name=vl_21_mngmt vlan-id=21
/ip address
add address=172.14.15.3/24 interface=vl_21_mngmt network=172.14.15.0
/ip dhcp-client
add disabled=no interface=ether1
/ip route
add distance=1 gateway=172.14.15.1
/system clock
set time-zone-name=Europe/Kiev
/system package update
set channel=development
Проверяем пинг на шлюз через 21 vlan tagged и работу dhcp на 22 vlan-е untagged:
/ping 172.14.15.1
SEQ HOST SIZE TTL TIME STATUS
0 172.14.15.1 56 64 0ms
1 172.14.15.1 56 64 0ms
2 172.14.15.1 56 64 0ms
3 172.14.15.1 56 64 0ms
4 172.14.15.1 56 64 0ms
5 172.14.15.1 56 64 0ms
6 172.14.15.1 56 64 0ms
7 172.14.15.1 56 64 0ms
8 172.14.15.1 56 64 0ms
sent=9 received=9 packet-loss=0% min-rtt=0ms avg-rtt=0ms max-rtt=0ms
/ip dhcp-client pr
Flags: X – disabled, I – invalid, D – dynamic
# INTERFACE USE-PEER-DNS ADD-DEFAULT-ROUTE STATUS ADDRESS
0 eth1_uplink yes yes bound 192.168.0.249/24
Всё хорошо, схема рабочая. Следующим примером должна была быть схема, где CRS выступает в роли маршрутизатора, но согласитесь, зачем вам одноядерный маршрутизатор с 10G портами, способный прожевать 100 Мбит трафика? Сейчас есть много вариантов, например тот же hEX (750Gr3) обладающий двухъядерным двух поточным процессором, способным обработать больше 400 Мбит. Мануал по настройке CRS в роли маршрутизатора вы всегда можете подчерпнуть на официальном wiki Mikrotik. Вместо этого я расскажу о кое-чём другом.
Bonding Router OS
Рис.7. Тестовый стенд Bonging
Bonging – это тот необходимый функционал, который спасает, когда нужно расширить канал связи, при этом не меняя магистральное оборудование. Для Bonding-а нужно всего лишь два волокна, но если волокно только одно, то можно прибегнуть к самому простому пассивному CWDM.
Начиная с RouterOS 6.42 все коммутаторы линейки CRS3xx поддерживают bonding на аппаратном уровне, но, к сожалению, поддержка ограничивается режимами 802.2ad (LASP) и XOR. Остальные режимы будут использовать ресурсы CPU, так что использовать их не имеет смысла.
Рис.8. Схема Bonding 802.11ad (LASP)
Убираю на всех устройствах всю конфигурацию с:
/interface bridge port
/interface bridge vlan
Начинаем с RB3011: собираем LASP с портов eth6-7 (все порты при агрегировании должны быть одного типа – витая пара или оптоволокно с одинаковой скоростью!), наруливаем vlan-ы, менедж.
/interface bonding add mode=802.3ad name=LASP_eth6-7 slaves=ether6,ether7
/interface bridge port add bridge=bridge interface=LASP_eth6-7
/interface bridge vlan
add bridge=bridge tagged=LASP_eth6-7,bridge vlan-ids=21
add bridge=bridge tagged=LASP_eth6-7,bridge untagged=ether5 vlan-ids=22
/interface vlan
add interface=LASP_eth6-7 name=vl_21_mngmt vlan-id=21
Дошла очередь до CRS: собираем LASP в две стороны, то есть на RB3011 и hEX, наруливаем вланы, менедж.
/interface bonding
add mode=802.3ad name=upl_LASP_eth23-24 slaves=ether23,ether24
add mode=802.3ad name=dwl_LASP_eth1-2 slaves=ether1,ether2
/interface bridge port
add bridge=bridge interface=upl_LASP_eth23-24
add bridge=bridge interface=dwl_LASP_eth1-2
/interface bridge vlan
add bridge=bridge tagged=upl_LASP_eth23-24,dwl_LASP_eth1-2,bridge vlan-ids=21
add bridge=bridge tagged=upl_LASP_eth23-24,dwl_LASP_eth1-2,bridge untagged=ether5 vlan-ids=22
Настройка управления не меняется, vlan 21 остаётся на bridge.
Полный конфиг CRS326-25G-2S+RM:
/interface bridge
add name=bridge vlan-filtering=yes
/interface vlan
add interface=bridge name=vl_21_mngmt vlan-id=21
/interface bonding
add mode=802.3ad name=dwl_LASP_eth1-2 slaves=ether1,ether2
add mode=802.3ad name=upl_LASP_eth23-24 slaves=ether23,ether24
/interface bridge vlan
add bridge=bridge tagged=upl_LASP_eth23-24,dwl_LASP_eth1-2,bridge vlan-ids=21
add bridge=bridge tagged=upl_LASP_eth23-24,dwl_LASP_eth1-2,bridge untagged=ether5 vlan-ids=22
/ip address
add address=172.14.15.2/24 interface=vl_21_mngmt network=172.14.15.0
/ip route
add distance=1 gateway=172.14.15.1
/system routerboard settings
set boot-os=router-os
Приступаем к hEX: настройка по аналогии с CRS, только предварительно сносим конфигурацию – interface bridge port, interface bridge vlan
/interface bonding
add mode=802.3ad name=upl_LASP_eth1-2 slaves=ether1,ether2 transmit-hash-policy=layer-2-and-3
/interface bridge port
add bridge=bridge interface=upl_LASP_eth1-2
add bridge=bridge interface=ether5 pvid=21
add bridge=bridge interface=ether4 pvid=22
/interface bridge vlan
add bridge=bridge tagged=bridge,upl_LASP_eth1-2 untagged=ether5 vlan-ids=21
add bridge=bridge tagged=upl_LASP_eth1-2 untagged=ether4 vlan-ids=22
Настройка управления не меняется, vlan 21 остаётся на bridge.
Лайфхак! При любом изменении конфигурации /interface bonding – vlan присвоенный данному интерфейсу нуждается в перезапуске, так как теряет статус Run и доступ к вашему оборудованию может быть утерян!
Итак, конфигурация готова, всё железки пингуются в 21 vlan-е, можно приступать к тестам с помощью Bandwidth test.
Рис.9. Bandwidth test LASP
LASP собран правильно, но из-за небольшой производительность RB3011 и hEX нагрузка CPU при генерировании трафика достигла 100% и мне не удалось прогнать больше 1.5 Гбит через CRS. Полтора гигабита трафика CRS будто не заметил, нагрузка не превысила 5%.
Лайфхак! Начиная с RouterOS 6.44beta39 Bandwidth test работает в многоядерном режиме, то есть использует все ядра/потоки CPU. Если вы желаете протестировать канал – обязательно обновите ОС, иначе многоядерные устройства не смогут использовать весь свой потенциал.
Теперь, когда известно, что Switch chip пропускает трафик мимо CPU и тесты трафиком больше не нужны – на стенде RB3011 сменяет RB2011UAS-2HnD-IN.
Ingress VLAN Router OS
Данное понятие расшифровывается, как возможность объединить два разных vlan-а в пределах одного коммутатора. Пример: к вам на пограничный коммутатор прилетает vlan с интернетом 22 , но этот vlan уже есть в вашей сети и сменить его на другой нет возможности, так как нужно перенастроить не один десяток свичей. Мы берём 22 vlan, загоняем его к нам на коммутатор, и там превращаем в 220 vlan, и он дальше уходит по магистрали с той же подсетью. Очень удобно, так делают многие мои коллеги, да и мне иногда приходится.
Рис.10. Схема vlan-ов (Ingress VLAN)
RB2011: настройки без изменений.
CRS326-25G-2S+RM: обнуляем настройки полностью и заново накатываем конфиг:
/interface bridge
add name=bridge protocol-mode=none vlan-filtering=no
/interface vlan
add interface=bridge name=vl_21_mngmt vlan-id=21
/interface wireless security-profiles
set [ find default=yes ] supplicant-identity=MikroTik
/interface bridge port
add bridge=bridge interface=sfp-sfpplus1
add bridge=bridge interface=ether1
/interface bridge vlan
add bridge=bridge tagged=bridge,sfp-sfpplus1,ether1 vlan-ids=21
add bridge=bridge tagged=ether1,bridge vlan-ids=220
add bridge=bridge tagged=sfp-sfpplus1,bridge vlan-ids=22
/interface ethernet switch rule
add new-dst-ports=ether1 new-vlan-id=220 ports=sfp-sfpplus1 switch=switch1 vlan-id=22
add new-dst-ports=sfp-sfpplus1 new-vlan-id=22 ports=ether1 switch=switch1 vlan-id=220
/ip address
add address=172.14.15.2/24 interface=vl_21_mngmt network=172.14.15.0
/ip route
add distance=1 gateway=172.14.15.1
/interface bridge set bridge vlan-filtering=ye
Переходим к hEX, тоже конфигурируем с нуля:
/interface ethernet
set [ find default-name=ether1 ] name=eth1_uplink
set [ find default-name=ether5 ] name=eth5_mngmt
/interface bridge
add name=bridge protocol-mode=none vlan-filtering=no
/interface vlan
add interface=bridge name=vl_21_mngmt vlan-id=21
add interface=bridge name=vl_220_dhcp vlan-id=220
/interface bridge port
add bridge=bridge interface=eth1_uplink
add bridge=bridge interface=ether2 pvid=220
add bridge=bridge interface=ether3 pvid=220
add bridge=bridge interface=ether4 pvid=220
add bridge=bridge interface=eth5_mngmt pvid=21
/interface bridge vlan
add bridge=bridge tagged=bridge,eth1_uplink untagged=eth5_mngmt vlan-ids=21
add bridge=bridge tagged=eth1_uplink,bridge untagged=ether2,ether3,ether4 vlan-ids=220
/ip address
add address=172.14.15.3/24 interface=vl_21_mngmt network=172.14.15.0
/ip dhcp-client
add disabled=no interface=vl_220_dhcp
/ip route
add distance=1 gateway=172.14.15.1
/interface bridge set bridge vlan-filtering=yes
Теперь проверяем, всё ли корректно работает. Наш стенд работает на ура – 22 vlan прилетает на конечное оборудование уже 220. Адреса RB750 успешно получает, интернет работает.
Рис.11. Проверка работоспособности схемы Ingress VLAN
SwOs
Коммутатор может работать под управлением всем знакомой RouterOS и не так распространённой SwOS, которая берёт свои корни с появлением RB260GS в 2010 году. С тех пор SwOS была забыта, обновления не выходили много лет, и для всех было неожиданностью, когда в 2017 году был представлен первый коммутатор с обновлённой SwOS 2.1. Этим самым коммутатором стала выше упомянутая модель CSS326-25G-2S+ RM. С тех компания Mikrotik вывела на рынок уже десяток коммутаторов и обновила SwOS до версии 2.11.
Лайфхак! Начиная с RouterOS 6.43 теперь из-под неё можно сохранять, загружать и сбрасывать конфигурацию SwOs, а так же можно установить обновления, а также загрузить готовый конфиг.
CRS326-25G-2S+ RM поддерживает SwOS начиная с версии 2.0, вся конфигурация происходит через браузер.
Даём команду на загрузку в SwOS:
system routerboard settings set boot-os=swos
Все настройки производятся в веб-интерфейсе, поэтому впереди много скринов.
Winbox видит все коммутаторы, поэтому узнать ip адрес не составляет труда, прописываем в настройки сетевой карты адрес из той же подсети что и наш CRS и через браузер залетаем на web-интерфейс.
Рис.12. Процедура входа на CRS
Первым делом переименовываю нужные нам порты.
Рис.13. Вкладка Link
Теперь пройдёмся по примерам типичных настроек vlan-ов.
Access and trunk SwOs
Рис.14. Стенд Access and trunk
Настройка RB2011 и RB750 те же что и на стенде Access and trunk Router OS, поэтому повторяться не буду.
Рис.15. Вкладка Vlan (Access and trunk)
Рис.16. Вкладка Vlans (Access and trunk)
Рис.17. Вкладка System
Лайфхак! Ip адрес управления на SwOs 2.11 не применяется до перезагрузки устройства!
Рис.18. Проверка стенда (Access and trunk)
Как видно на скринах, конфигурация рабочая, жаль только что в SwOs не реализовали terminal, было бы очень удобно.
Trunk and hybrid ports SwOs
На RB2011 и RB750 накатываем те же настройки, как и на стенде Trunk and hybrid ports Router OS.
Переходим к настройке CRS: sfpplus1 принимаем 21, 22 vlan-ы tagged, с eth1 на hEX (750Gr3) отправляем 21 vlan tagged, 22 vlan untagged.
Во вкладке VLANs ничего не поменялось. А вот вкладка VLAN претерпела изменения – на ether1 в сторону RB750 Default VLAN ID указываем 22.
Рис.19. Вкладка Vlan (Trunk and hybrid ports)
Рис.20. RB750: 21 vlan tagged, 22 vlan untagged
Bonding SwOs
На устройствах CRS3xx можно поднимать LASP даже под управлением SwOs, что я сейчас и постараюсь сделать.
Рис.21. Стенд LASP
На RB2011 и RB750 накатываем те же настройки, что и на стенде.
На CRS-е добавляем 21, 22 vlan-ы на порты, где будет поднят LASP. Сам bonding настраивается на вкладке LAG, здесь всё максимально просто, CRS сам подскажет, что на этих портах с другой стороны поднят LASP, и автоматически включит LASP на этих портах. Можно вручную выбрать Mode –static и указать к какой группе пренадлежит порт.
Рис.22. Вкладка LAG
Рис.23. Проверка работоспособности LASP
Проверка прошла успешно, трафик равномерно распределяется между портами.
CRS326-25G-2S+ RM получился отлично сбалансированным коммутатором, да есть некоторые программные баги, но их вскоре пофиксят в следующих версиях ПО, но за такой прайс, вы вряд ли найдёте альтернативу.
Инженеры создали отличную линейку управляемых коммутаторов, которые заняли бюджетную нишу в сегменте PoE, 10G, 40G коммутаторов. Так же не стоит забывать о недавно вышедших всепогодных моделях, в том числе и новинку netPower, с помощью которой Mikrotik хочет продвинуть свою концептуальную технологию GPEN. Отдельно хочется сказать о развитии RouterOS, в которой после версии 6.45 кардинально поменялись приципы настройки vlan-ов. А в начале года вышла долгожданная ROS v7, правда глобальные изменения пока что под “капотом”, так ядро Linux обновился с версии 3.3.5 до 4.14.131. В бете анонсирована полноценная поддержка многоядерности при обработке BGP. Так же в будущем нас ждёт новый движок маршрутизации. SwOs которую не так давно воскресили из мёртвых тоже набирает оборотов, думаю вскорее её функционал серьёзно разрастётся, но это будет уже ближе к 3 версии, правда поддерживать её будут только новые модели с увеличенной ПЗУ и ОЗУ.
Вообщем компания Mikrotik идёт семимильными шагами как в хардварном, так и в софтверном направлениях, и в будущем от этих ребят можно ожидать чего угодно!
Вас может заинтересовать
Если Вы нашли ошибку в тексте, то выделите ее мышкой и нажмите Ctrl + Enter или нажмите здесь.
Сообщение об ошибке
Ошибка:
Ваш комментарий (не обязательно):
Отличная статья, вот только не понятно почему на RB3011 приходящий vlan с интернетом сразу вешается на интерфейс eth1 а не создаётся бридж и уже на него навешивается vlan
Тому що, задача полягає не в тому, щоб пропустити даний VLAN далі в мережу, а опрацювати трафік, що приходить по ньому від провайдера.